# show all commands
default:
  just --list --unsorted

# build htmls
html:
  make

# dev
dev:
  ls src/*.md | entr just html

# copy assets to www
assets:
  cp assets/* www/

alias all := up
# upload it
up: html rss
  rsync -azP --exclude=.git www/* tilde:public_html/clericthief/

# make episodes rss
episoderss:
  echo "<rss version=\"2.0\"><channel><title>cleric + thief</title>" > www/episodes.xml \
  && echo "<link>http://tilde.town/~dozens/clericthief/index.html</link><description>adventures of iofi and maddox</description><atom:link rel=\"self\" type=\"application/rss+xml\" href=\"http://tilde.town/~dozens/clericthief/episodes.xml\"/>" >> www/episodes.xml \
  && echo i \
  | cat - src/index.md ed/blogitem.ed \
  | ed -s \
  | recfmt -f templates/blogitem.rec.template \
  | m4 \
  >> www/episodes.xml \
  && echo '</channel></rss>' >> www/episodes.xml

# make journal rss
journalrss:
  echo "<rss version=\"2.0\"><channel><title>cleric + thief</title>" > www/journal.xml \
  && echo "<link>http://tilde.town/~dozens/clericthief/index.html</link><description>behind the scenes of cleric + thief</description><atom:link rel=\"self\" type=\"application/rss+xml\" href=\"http://tilde.town/~dozens/clericthief/journal.xml\"/>" >> www/journal.xml \
  && echo i \
  | cat - src/journal.md ed/journalitem.ed \
  | ed -s \
  | recfmt -f templates/journalitem.rec.template \
  | m4 \
  >> www/journal.xml \
  && echo '</channel></rss>' >> www/journal.xml

# build all rss
rss: episoderss journalrss

# one random NPC
npc:
  @recsel -P name,note -m 1 db/npc.rec

# one random plot thread
thread:
  @recsel -P name,note -m 1 db/threads.rec